FS:=75;
分数MIN:=IF(MACHINEDATE<094500,FS-15,IF(MACHINEDATE<100000,FS-10,IF(MACHINEDATE<130000,FS-5,FS)));

{多维度市场牛熊状态模型}
N1:=21;
N2:=55;
VOL_RATIO:=1.2;
ATR_PERIOD:=14;
ANGLE:=5;

EMA_INDEX:=EMA(INDEXC,N1);
LONG_EMA_INDEX:=EMA(INDEXC,N2);
TREND_ANGLE:=IF(REF(EMA_INDEX,5)!=0, ATAN((EMA_INDEX/REF(EMA_INDEX,5)-1)*100)*180/3.1416, 0);
VOL_MA:=MA(INDEXV,N2);

INDEX_ATR:=MA(TR,ATR_PERIOD);
LOW_VOLATILITY:=INDEX_ATR/REF(INDEX_ATR,5)<0.7;

COND_BULL:=
    EMA_INDEX > LONG_EMA_INDEX AND
    COUNT(TREND_ANGLE>ANGLE,3)>=2 AND 
    EVERY(INDEXV>VOL_MA*VOL_RATIO,3) AND 
    NOT(LOW_VOLATILITY);

COND_BEAR:=
    EMA_INDEX < LONG_EMA_INDEX AND
    COUNT(TREND_ANGLE<-ANGLE,3)>=2 AND
    EVERY(INDEXV<VOL_MA*0.7,3) AND
    INDEX_ATR > REF(INDEX_ATR,5)*1.3;

HY_EMA:=EMA(HY_INDEXC,N1);
HY_TREND_ANGLE:= IF(REF(HY_EMA,5)!=0, ATAN((HY_EMA/REF(HY_EMA,5)-1)*100)*180/3.1416, 0);
STRONG_INDUSTRY:=
    HY_EMA > EMA(HY_INDEXC,N2) AND
    HY_TREND_ANGLE > ANGLE AND
    COUNT(HY_INDEXV>MA(HY_INDEXV,N2)*VOL_RATIO,5)>=3;

WEAK_INDUSTRY:=
    HY_EMA < EMA(HY_INDEXC,N2) AND
    HY_TREND_ANGLE < -ANGLE AND
    MA(HY_INDEXV,N2)/REF(MA(HY_INDEXV,N2),5)<0.8;

HS300C:="SZ399300$CLOSE";
REL_STR:=(C/REF(C,N1))/(HS300C/REF(HS300C,N1))-1;
IND_BULL:=FILTER(REL_STR>0.12 AND REL_STR>REF(REL_STR,1),3);
IND_BEAR:=FILTER(REL_STR<-0.18 AND REL_STR<REF(REL_STR,1),3);

WEEK_EMA:=EMA(C#WEEK,5);
WEEK_TREND:=WEEK_EMA>REF(WEEK_EMA,3);

BULL_SCORE:=(COND_BULL + STRONG_INDUSTRY + IND_BULL + WEEK_TREND)>=3;
BEAR_SCORE:=(COND_BEAR + WEAK_INDUSTRY + IND_BEAR + NOT(WEEK_TREND))>=3;

MARKET:=IF(BULL_SCORE,1, IF(BEAR_SCORE,2,3));{1:牛市,2:熊市,3:震荡市或不确定};

{动态阈值设定，满分100}

权重主力 :=IF(MARKET==1,	50, IF(MARKET==3,		35,		40));
权重量价 :=IF(MARKET==1,	20, IF(MARKET==3,		 5,		10));
权重板块 :=IF(MARKET==1,	30, IF(MARKET==3,		15,		30));
权重资效 :=IF(MARKET==1,	 0, IF(MARKET==3,		20,		5));
权重波动 := IF(MARKET==1,	 0, IF(MARKET==3,		10,		5));
权重趋势 := IF(MARKET==1,	 0, IF(MARKET==3,		5,		5));
权重风险 := IF(MARKET==1, 	 0, IF(MARKET==3,		10,		5));

{主力资金动态捕捉}
权重DDX:=权重主力*0.6;
权重DDY:=权重主力*0.4;


_DDX:=(LARGEINTRDVOL-LARGEOUTTRDVOL)*10000/FINANCE(7);
_DDY:=IF(TRADENUM>0,(TRADEOUTNUM-TRADEINNUM)*100/TRADENUM,0);

资金分DDX:= IF(_DDX>1.4, 权重DDX, IF(_DDX>1.2, 权重DDX-1, IF(_DDX>1.0, 权重DDX-2, IF(_DDX>0.8, 权重DDX-3, IF(_DDX>0.6, 权重DDX-4, IF(_DDX>0.3, 权重DDX-5, 0))))));
资金分DDY:= IF(_DDY>50, 权重DDY, IF(_DDY>40, 权重DDY-1, IF(_DDY>30, 权重DDY-2, IF(_DDY>20, 权重DDY-3, IF(_DDY>15, 权重DDY-4, 0)))));

资金分:=资金分DDX + 资金分DDY;

{量价动能共振模型}
量比:=DYNAINFO(17);
量比MIN:=IF (TIME<1000,3,IF (TIME<1430, 2, 1.5));
量比判断:=量比 > 量比MIN;

现价:=DYNAINFO(7);
分时均价:=DYNAINFO(11);

当前涨幅:=(C-REF(C,1))/REF(C,1)*100;
涨幅扩大:=当前涨幅 > MA(当前涨幅,5) AND 当前涨幅 > REF(当前涨幅,1);

RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
KDJ上限:=90;

量价初始分:=IF(量比判断, 权重量价*0.4, 0)  + IF(现价>分时均价, 权重量价*0.4, 0)  + IF(涨幅扩大, 权重量价*0.2, 0);
量价分:=IF(MARKET==1, 量价初始分, IF(J<KDJ上限,	量价初始分,	0));


{板块效应强化机制}
行业排名:=HORCALC(HYBLOCK, 105, 1, 0);
行业热度:=HORCALC(HYBLOCK, 105, 2, 0)*100;

板块分:=IF(行业热度>=0, 
		ROUND(
		IF(行业排名<=2, 权重板块*0.6, 
		IF(行业排名<=3, 权重板块*0.5, 
		IF(行业排名<=5, 权重板块*0.4, 
		IF(行业排名<=10, 权重板块*0.2, 
		0))))
          + IF(行业热度>=3, 权重板块*0.4, 
			IF(行业热度>=2, 权重板块*0.3,  
			IF(行业热度>=1, 权重板块*0.2, 
		0)))),
		0);

{资金效率筛选}
成交额万元 := DYNAINFO(8)/10000;  
行业平均涨幅 := 100 * HORCALC(HYBLOCK, 105, 2, 0);  
超额涨幅 := 当前涨幅 - 行业平均涨幅; 
阈值 := MA(VOL,20)/10000;
资金效率 := IF(成交额万元 > 阈值 AND 成交额万元 > 0, 超额涨幅 / LOG(成交额万元), 0);  
资效分:=IF(资金效率 >= 2, 权重资效, 
		IF(资金效率 >= 1.5, 权重资效*0.8, 
		IF(资金效率 >= 1.0, 权重资效*0.6, 
		IF(资金效率 >= 0.5, 权重资效*0.4, 
		0)))); 

{夏普比率筛选器}
RF := 0.025;     {2025年最新无风险利率(2.5%)}
日收益率 := IF(REF(C,1)!=0, C/REF(C,1)-1, 0);  
年化收益 := (EMA(日收益率,20)*252) - RF;  
年化波动 := (STD(日收益率,20)+0.0001)*SQRT(252);  
夏普值 := 年化收益 / 年化波动;
夏普阈值 := IF(年化波动>0.3, 0.5, 0.8);
波动分:=IF(夏普值>夏普阈值 AND 夏普值>=8,权重波动,
		IF(夏普值>夏普阈值 AND 夏普值>=6,权重波动*0.8,
		IF(夏普值>夏普阈值 AND 夏普值>=4,权重波动*0.6,
		IF(夏普值>夏普阈值 AND 夏普值>=2,权重波动*0.4,
		IF(夏普值>夏普阈值 AND 夏普值>=1,权重波动*0.2,
		0)))));

{趋势判断}
短期穿越1:= 现价 > MA(C,5);
短期穿越2:= MA(C,5) > MA(C,10);
短期穿越3:= MA(C,10) < MA(C,20);
换手率下限:=IF (MACHINETIME<094500,0.1,IF (MACHINETIME<100000, 0.15, 0.2));
换手率条件:=DYNAINFO(36)<换手率下限;
趋势分:=IF(换手率条件 AND 短期穿越1 AND 短期穿越2 AND 短期穿越3, 权重趋势,
		IF(换手率条件 AND 短期穿越1 AND 短期穿越2, 权重趋势*0.5,
		IF(换手率条件 AND 短期穿越1, 权重趋势*0.2,
		0)));

{风险控制与信号强化}
大盘趋势:=INDEXC > MA(INDEXC,50) AND (DYNAINFO(60)/(DYNAINFO(60)+DYNAINFO(61)))>0.3;
流通市值过滤:=FINANCE(40)/100000000;
流通市值达标:=流通市值过滤>20;
市盈率条件:=IF(DYNAINFO(40)>0 AND DYNAINFO(40)<=HYSYL*1.1,1,0);
风险分:=IF(SAFESCORE>80,
			IF(流通市值达标, 权重风险*0.2, 0) 
          + IF(市盈率条件, 权重风险*0.3, 0) 
          + IF(大盘趋势, 权重风险*0.5, 0)
		,0);

{量比过小不买}
量比下限:=0.8;
市盈率极限:=IF(DYNAINFO(40)<=0 OR DYNAINFO(40)>300,1,0);
其他分:=IF(量比<=量比下限,-10,0)+IF(市盈率极限,-10,0);


{不是有效代码直接得分为0}
沪市主板:=CODELIKE('60') AND NOT(CODELIKE('688')); 
深市主板:=CODELIKE('000') OR CODELIKE('001') OR CODELIKE('002')  OR CODELIKE('30'); 
有效代码:=沪市主板 OR 深市主板 AND NOT(NAMELIKE('ST'));


{总分计算（满分100）}
信号强度:= (资金分 + 量价分 + 板块分 + 资效分 + 波动分 + 趋势分 + 风险分 + 其他分) * 有效代码;

买入阈值:=IF(MARKET==1,分数MIN+5, IF(MARKET==3,分数MIN-5,分数MIN));

{即时价格必须小于某涨幅}
最高涨幅:=(H-REF(C,1))/REF(C,1)*100;
涨幅上限:=IF((CODELIKE('688') OR CODELIKE('30')), 12, 6);

买入信号:信号强度>=买入阈值 AND 最高涨幅<涨幅上限;